-heap  0x8000
-stack 0x1000

MEMORY
{
        /* Local L2, 0.5~1MB*/
        VECTORS:              o = 0x00800000  l = 0x00000200   
        LL2_CODE:             o = 0x00800200  l = 0x0001FE00
        LL2_DATA:             o = 0x00820000  l = 0x00020000
    
        /* Shared L2 1MB for C6657*/
        SL2_CODE:             o = 0x0C000000  l = 0x00080000
        SL2_DATA:             o = 0x0C080000  l = 0x00040000
        //remap 256KB SL2 from 0x0C180000 to 0x18000000
        SL2_REMAP:            o = 0x18000000  l = 0x00040000
    
        /* External DDR3, upto 2GB per core */
        DDR3_CODE:            o = 0x80000000  l = 0x01000000
        DDR3_DATA:            o = 0x81000000  l = 0x05000000
        DDR3_Profile_DATA:    o = 0x86000000  l = 0x02000000
        DDR3_ECC_DATA:        o = 0x88000000  l = 0x01000000
}

SECTIONS
{
        vecs                            > VECTORS 
        .text                           > SL2_CODE
        .cinit                          > SL2_DATA
        .const                          > SL2_DATA
        .switch                         > SL2_DATA
    
        .stack: fill= 0xBFBFBFBF        > LL2_DATA
        GROUP
        {
            .neardata
            .rodata
            .bss
        }                               > LL2_DATA
        .far                            > LL2_DATA
        .fardata                        > LL2_DATA
        .cio                            > LL2_DATA
        .sysmem                         > LL2_DATA
                                        
        .text:Core_MPAX                 > LL2_CODE
        ll2EDCCode                      > LL2_CODE
        ll2EDCData                      > LL2_DATA
        ll2MPData                       > LL2_DATA
    
        Sl2EDCCode                      > SL2_CODE
        Sl2EDCData                      > SL2_DATA
        sl2MPData_w                     > SL2_DATA
        sl2MPData_r                     > SL2_DATA
        msmcSmsMPData_w                 > SL2_DATA
        msmcSmsMPData_r                 > SL2_DATA
        QMSS_Data.Descriptor_SL2        > SL2_DATA
        PacketData.buffer_SL2           > SL2_DATA
    
        ddr3MPData_w                    > DDR3_DATA
        ddr3MPData_r                    > DDR3_DATA
        msmcSesMPData_w                 > DDR3_DATA
        msmcSesMPData_r                 > DDR3_DATA
        ETBLib_dmaData                  > DDR3_DATA
        .far:External_NonCache_Data     > DDR3_Profile_DATA
        DDRECCData                      > DDR3_ECC_DATA
}


