Part Number: OPA627
Other Parts Discussed in Thread: TINA-TI,
在第二部分中，我们曾介绍过运算放大器噪声模型，它包括运算放大器、电压噪声源和电流噪声源。我们将用分离噪声源和通用运算放大器来构建这一噪声模型。模拟与 Rf 模型 (Analog & Rf models) 公司的Bill Sands为 TI 开发了分离噪声源。您可从 TI 网站 www.ti.com下载这种噪声源，只需搜索 “TINA-TI 应用原理图” 并查找 “噪声分析”文件夹即可。我们还在附录 4.1 和 4.2 中给出了“ TINA 宏”列表。
图 4.8 显示了用于创建噪声模型的电路。请注意，这就是我们此前使用的测试电路配置。该电路配置中有一个连接在输入端之间的电流噪声源。严格地说，实际上有两个电流噪声源。不过，我们从产品说明书很难说清楚这些信号源之间的相互关系。而且，在电流反馈放大器中这些信号源的信号幅度不同。我们在以后的文章中将更详细地探讨上述问题。我们将对电路加以定制，以便对 OPA627 的噪声特点进行适当建模。
附录 4.1：电压噪声宏
* BEGIN PROG NSE NANO VOLT/RT-HZ
.SUBCKT VNSE 1 2
* BEGIN SETUP OF NOISE GEN - NANOVOLT/RT-HZ
* INPUT THREE VARIABLES
* SET UP VNSE 1/F
* NV/RHZ AT 1/F FREQ
.PARAM NLF=15
* FREQ FOR 1/F VAL
.PARAM FLW=10
* SET UP VNSE FB
* NV/RHZ FLATBAND
.PARAM NVR=4.5
* END USER INPUT
* START CALC VALS
.PARAM GLF={PWR(FLW,0.25)*NLF/1164}
.PARAM RNV={1.184*PWR(NVR,2)}
.MODEL DVN D KF={PWR(FLW,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVN
D2 8 0 DVN
E1 3 6 7 8 {GLF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNV}
R5 5 0 {RNV}
R6 3 4 1E9
R7 4 0 1E9
E3 1 2 3 4 1
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
·END PROG NSE NANOV/RT-HZ
附录 4.2：电流噪声宏
* BEGIN PROG NSE FEMTO AMP/RT-HZ
.SUBCKT FEMT 1 2
* BEGIN SETUP OF NOISE GEN - FEMPTOAMPS/RT-HZ
* INPUT THREE VARIABLES
* SET UP INSE 1/F
* FA/RHZ AT 1/F FREQ
.PARAM NLFF=2.5
* FREQ FOR 1/F VAL
.PARAM FLWF=0.001
* SET UP INSE FB
* FA/RHZ FLATBAND
.PARAM NVRF=2.5
* END USER INPUT
* START CALC VALS
.PARAM GLFF={PWR(FLWF,0.25)*NLFF/1164}
.PARAM RNVF={1.184*PWR(NVRF,2)}
.MODEL DVNF D KF={PWR(FLWF,0.5)/1E11} IS=1.0E-16
* END CALC VALS
I1 0 7 10E-3
I2 0 8 10E-3
D1 7 0 DVNF
D2 8 0 DVNF
E1 3 6 7 8 {GLFF}
R1 3 0 1E9
R2 3 0 1E9
R3 3 6 1E9
E2 6 4 5 0 10
R4 5 0 {RNVF}
R5 5 0 {RNVF}
R6 3 4 1E9
R7 4 0 1E9
G1 1 2 3 4 1E-6
C1 1 0 1E-15
C2 2 0 1E-15
C3 1 2 1E-15
.ENDS
* END PROG NSE FEMTO AMP/RT-HZ
