[参考译文] MSP432E401Y：无法调试/遍历引导加载程序代码。

我使用了以太网引导加载程序，我认为这是类似的。 问题是引导加载程序将自身复制到 RAM，并从 RAM 中运行。 源代码认为它位于 RAM 中的执行地址，而不是闪存中的链接地址，因此，您必须使用一些技巧，直到找到调试器知道它所在的 RAM 中运行的代码。

代码以 BL_STARTUAL_CCS.s (在项目的 CCS 文件夹中)开头。
该文件包含指向 ResetISR 函数的矢量表。

ResetISR: .asmfunc
;;
;; Enable the floating-point unit. This must be done here in case any
;; later C functions use floating point. Note that some toolchains will
;; use the FPU registers for general workspace even if no explicit floating
;; point data types are in use.
;;
movw r0, #0xED88
movt r0, #0xE000
ldr r1, [r0]
orr r1, r1, #0x00F00000
str r1, [r0]
 
;;
;; Initialize the processor.
;;
bl ProcessorInit

如果启动调试器，它应在 ResetISR 处停止。 打开汇编程序调试窗口，您会看到如下内容：

000032b0:   F64E5088            movw       r0, #0xed88
000032b4:   F2CE0000            movt       r0, #0xe000
000032b8:   6801                ldr        r1, [r0]
000032ba:   F4410170            orr        r1, r1, #0xf00000
000032be:   6001                str        r1, [r0]
000032c0:   F7FFFFD8            bl         #0x3274
000032c4:   F000FBA2            bl         #0x3a0c

然后，您应该看到如下内容：

00003274:   2000                movs       r0, #0
00003276:   2100                movs       r1, #0
00003278:   F2C20100            movt       r1, #0x2000
0000327c:   F85F2014            ldr.w      r2, [pc, #-0x14]
00003280:   F8503B04            ldr        r3, [r0], #4
00003284:   F8413B04            str        r3, [r1], #4
00003288:   4291                cmp        r1, r2
0000328a:   DBF9                blt        #0x3280
0000328c:   2000                movs       r0, #0
0000328e:   F85F2020            ldr.w      r2, [pc, #-0x20]
00003292:   F8410B04            str        r0, [r1], #4
00003296:   4291                cmp        r1, r2
00003298:   DBFB                blt        #0x3292
0000329a:   F64E5008            movw       r0, #0xed08
0000329e:   F2CE0000            movt       r0, #0xe000
000032a2:   2100                movs       r1, #0
000032a4:   F2C20100            movt       r1, #0x2000
000032a8:   6001                str        r1, [r0]
000032aa:   F04E5E00            orr        r14, r14, #0x20000000
000032ae:   4770                bx         r14

该文件的来源位于同一文件中：

ProcessorInit: .asmfunc
;;
;; Copy the code image from flash to SRAM.
;;
movs r0, #0x0000
movs r1, #0x0000
movt r1, #0x2000
ldr r2, bss_start
copy_loop:
ldr r3, [r0], #4
str r3, [r1], #4
cmp r1, r2
blt copy_loop
 
;;
;; Zero fill the .bss section.
;;
movs r0, #0x0000
ldr r2, bss_end
zero_loop:
str r0, [r1], #4
cmp r1, r2
blt zero_loop
 
;;
;; Set the vector table pointer to the beginning of SRAM.
;;
movw r0, #(0xE000ED08 & 0xffff)
movt r0, #(0xE000ED08 >> 16)
movs r1, #0x0000
movt r1, #0x2000
str r1, [r0]
 
;;
;; Set the return address to the code just copied into SRAM.
;;
orr lr, lr, #0x20000000
 
;;
;; Return to the caller.
;;
bx lr
.endasmfunc

最后一条线就是魔法发生的地方！

Orr LR，LR，#0x20000000

(看起来像 Orr     调试器中的 R14，r14，#0x20000000)

正在将函数的返回地址修改为呼叫者的等效位置，但在 RAM 副本中，请运行到该行，然后执行单步操作并进入

BX LR

现在，我们刚刚接到 ProcessorInit 的电话，但在 RAM 中，源调试器似乎能够应对这一问题。

我认为 UART 引导加载程序在启动时没有太大的区别-希望这能有所帮助。

Jim，您好，谢谢您的回复。

最后一条线就是魔法发生的地方！

Orr LR，LR，#0x20000000

(看起来像 Orr     调试器中的 R14，r14，#0x20000000)

正在将函数的返回地址修改为呼叫者的等效位置，但在 RAM 副本中，请运行到该行，然后执行单步操作并进入

BX LR

现在，我们刚刚接到 ProcessorInit 的电话，但在 RAM 中，源调试器似乎能够应对这一问题。

我认为 UART 引导加载程序在启动时没有太大的区别-希望这能有所帮助。

感谢您的解释。  我能够像你所建议的那样进入消息来源。