[参考译文] TMS570LC4357：版本构建中但调试构建中不存在 ECC 错误

尊敬的 Jagadish：  

通过修改.cmd 文件并在链接器 (CCS) 中启用--ecc=on 选项、我在将准确的 ECC 值填充到指定的闪存 ECC 空间 0xF0400000 上取得了一些成功（这第二步从所有关于链接器生成的 ECC 的指南中都缺失、应由 TI 团队在必要时进行更新）。  

 我的想法是存储产生故障的闪存的 64 位对齐地址、关于数据被字节掩蔽、仍然不明白这是什么意思。 运气好吗？

此外、我还附上了我的工作.cmd 文件、供感兴趣的任何人参考。

谢谢您、  
Prajwal T R

MEMORY
{
/* USER CODE BEGIN (2) */
/* USER CODE END */
    VECTORS (X)  : origin=0x00000000 length=0x00000020 vfill=0xFFFFFFFF
    FLASH0  (RX) : origin=0x00000020 length=0x001FFFE0 vfill=0xFFFFFFFF
    FLASH1  (RX) : origin=0x00200000 length=0x00200000 vfill=0xFFFFFFFF
    STACKS  (RW) : origin=0x08000000 length=0x00001500
    RAM     (RW) : origin=0x08001500 length=0x0007EB00

/* USER CODE BEGIN (3) */
    ECC_VEC  (R) : origin=(0xf0400000 + (start(VECTORS) >> 3))
                   length=(size(VECTORS) >> 3)
                   ECC={algorithm=algoL2R5F021, input_range=VECTORS}

    ECC_FLA0 (R) : origin=(0xf0400000 + (start(FLASH0)  >> 3))
                   length=(size(FLASH0)  >> 3)
                   ECC={algorithm=algoL2R5F021, input_range=FLASH0 }

    ECC_FLA1 (R) : origin=(0xf0400000 + (start(FLASH1)  >> 3))
                   length=(size(FLASH1)  >> 3)
                   ECC={algorithm=algoL2R5F021, input_range=FLASH1 }

/* USER CODE END */
}

/* USER CODE BEGIN (4) */
ECC
{
    algoL2R5F021 : address_mask = 0xfffffff8 /* Address Bits 31:3 */
                   hamming_mask = R4         /* Use R4/R5 build in Mask */
                   parity_mask  = 0x0c       /* Set which ECC bits are Even and Odd parity */
                   mirroring    = F021       /* RM57Lx and TMS570LCx are build in F021 */
}
/* USER CODE END */


/*----------------------------------------------------------------------------*/
/* Section Configuration                                                      */

SECTIONS
{
/* USER CODE BEGIN (5) */
/* USER CODE END */
    .intvecs : {} > VECTORS
    .text   palign(8) : {} > FLASH0 | FLASH1
    .const  palign(8) : {} > FLASH0 | FLASH1
    .cinit  palign(8) : {} > FLASH0 | FLASH1
    .pinit  palign(8) : {} > FLASH0 | FLASH1
    .bss     : {} > RAM
    .data    : {} > RAM
    .sysmem  : {} > RAM
	

/* USER CODE BEGIN (6) */
/* USER CODE END */
}