请注意，本文内容源自机器翻译，可能存在语法或其它翻译错误，仅供参考。如需获取准确内容，请参阅链接中的英语原文或自行翻译。
器件型号：TMDSCNCD28379D 主题中讨论的其他器件： C2000WARE
您好！
当在针对 CPU2的 TMDSCNCD28379D 的 MATLAB Simulink 中尝试外部模式(从闪存引导)时、我已经在 CPU1上运行了一个不同的应用(从闪存引导)、我收到一个错误消息"程序将不适合可用存储器"
<Linking> warning: build attribute vendor section TI missing in "C:/ProgramData/MATLAB/SupportPackages/R2018a/toolbox/target/supportpackages /tic2000/rtlib/IQmath_fpu32.lib<IQ10div.obj>": compatibility cannot be determined warning: build attribute vendor section TI missing in "C:/ProgramData/MATLAB/SupportPackages/R2018a/toolbox/target/supportpackages /tic2000/rtlib/IQmath_fpu32.lib<IQmathTables.obj>": compatibility cannot be determined "C:/ProgramData/MATLAB/SupportPackages/R2018a/toolbox/target/supportpackages/tic2000/src/c28377D.cmd", line 131: error: program will not fit into available memory. run placement with alignment/blocking fails for section ".ebss" size 0x8e7 page 1. Available memory ranges: RAMLS_DATA size: 0x2000 unused: 0x0 max hole: 0x0 RAMD1 size: 0x800 unused: 0x0 max hole: 0x0 error: errors encountered during linking; "../Inverter_003.out" not built >> Compilation failure gmake: *** [../Inverter_003.out] Error 1
主要部分是：
RAMLS_DATA 大小：0x2000未使用：0x0最大空洞：0x0
RAMD1大小：0x800未使用：0x0最大孔：0x0
此答复 建议进入链接器文件并向堆区域添加更多段。
当我转到链接器文件 C：\ProgramData\MATLAB SupportPackages\R2018a\toolbox\target\supportpackages/tic2000\src\c28377D.cmd 时
问题1. 我看不到.sysmem、只有.esysmem。 这是问题吗？
.esysmem ：>RAMLS_DATA， PAGE = 1.
问题2. CPU1只有#ifdef CPU1、CPU2没有。 这是问题吗？
问题3. 我在链接器文件中看不到可作为或("|")添加的可用存储器、仅 RAMLS_DATA。 我应该修改 RAMLS_DATA 吗？ 下面是完整的链接器文件
#ifdef CLA_BLOCK_INCLUDED
// Define a size for the CLA scratchpad area that will be used
// by the CLA compiler for local symbols and temps
// Also force references to the special symbols that mark the
// scratchpad are.
CLA_SCRATCHPAD_SIZE = 0x100;
--undef_sym=__cla_scratchpad_end
--undef_sym=__cla_scratchpad_start
#endif //CLA_BLOCK_INCLUDED
MEMORY
{
PAGE 0 :
/* BEGIN is used for the "boot to SARAM" bootloader mode */
BEGIN : origin = 0x000000, length = 0x000002
BEGIN_FLASH : origin = 0x080000, length = 0x000002
#ifdef CPU1
RAMM0 : origin = 0x000122, length = 0x0002DE
#else
RAMM0 : origin = 0x000080, length = 0x000380
#endif
RAMD0 : origin = 0x00B000, length = 0x000800
#ifdef CLA_BLOCK_INCLUDED
RAMLS_PROG : origin = 0x00A000, length = 0x000800
RAMLS_CLA_PROG : origin = 0x00A800, length = 0x000800
#else
RAMLS_PROG : origin = 0x009000, length = 0x002000
#endif //CLA_BLOCK_INCLUDED
#ifdef CPU1
#if BOOT_FROM_FLASH
RAMGS_PROG : origin = 0x017000, length = 0x001000
#else
RAMGS_PROG : origin = 0x014000, length = 0x004000
#endif
#endif
RESET : origin = 0x3FFFC0, length = 0x000002
/* Flash sectors */
FLASHA_N : origin = 0x080002, length = 0x03FFFE /* on-chip Flash */
PAGE 1 :
#ifdef CPU1
BOOT_RSVD : origin = 0x000002, length = 0x000120 /* Part of M0, BOOT rom will use this for stack */
#else
BOOT_RSVD : origin = 0x000002, length = 0x00007E /* Part of M0, BOOT rom will use this for stack */
#endif
RAMM1 : origin = 0x000400, length = 0x000400 /* on-chip RAM block M1 */
RAMD1 : origin = 0x00B800, length = 0x000800
#ifdef CLA_BLOCK_INCLUDED
RAMLS_CLA_DATA : origin = 0x008000, length = 0x001000
RAMLS_DATA : origin = 0x009000, length = 0x002000
#else
RAMLS_DATA : origin = 0x008000, length = 0x002000
#endif //CLA_BLOCK_INCLUDED
#ifdef CPU1
#if BOOT_FROM_FLASH
RAMGS_DATA : origin = 0x00E000, length = 0x00B000
#else
RAMGS_DATA : origin = 0x00E000, length = 0x008000
#endif
#endif
RAMGS_IPCBuffCPU1 : origin = 0x00C000, length = 0x001000
RAMGS_IPCBuffCPU2 : origin = 0x00D000, length = 0x001000
CLA1_MSGRAMLOW : origin = 0x001480, length = 0x000080
CLA1_MSGRAMHIGH : origin = 0x001500, length = 0x000080
CPU2TOCPU1RAM : origin = 0x03F800, length = 0x000400
CPU1TOCPU2RAM : origin = 0x03FC00, length = 0x000400
}
SECTIONS
{
#if BOOT_FROM_FLASH
/* Allocate program areas: */
.cinit : > FLASHA_N PAGE = 0, ALIGN(4)
.pinit : > FLASHA_N, PAGE = 0, ALIGN(4)
.text : > FLASHA_N PAGE = 0, ALIGN(4)
codestart : > BEGIN_FLASH PAGE = 0, ALIGN(4)
ramfuncs : LOAD = FLASHA_N,
RUN = RAMLS_PROG,
LOAD_START(_RamfuncsLoadStart),
LOAD_SIZE(_RamfuncsLoadSize),
LOAD_END(_RamfuncsLoadEnd),
RUN_START(_RamfuncsRunStart),
RUN_SIZE(_RamfuncsRunSize),
RUN_END(_RamfuncsRunEnd),
PAGE = 0, ALIGN(4)
/* Initalized sections go in Flash */
.econst : > FLASHA_N PAGE = 0, ALIGN(4)
.switch : > FLASHA_N PAGE = 0, ALIGN(4)
/* Allocate IQmath areas: */
IQmath : > FLASHA_N, PAGE = 0, ALIGN(4) /* Math Code */
IQmathTables : > FLASHA_N, PAGE = 0, ALIGN(4)
#ifdef CLA_BLOCK_INCLUDED
/* CLA specific sections */
Cla1Prog : LOAD = FLASHA_N,
RUN = RAMLS_CLA_PROG,
LOAD_START(_Cla1funcsLoadStart),
LOAD_END(_Cla1funcsLoadEnd),
RUN_START(_Cla1funcsRunStart),
LOAD_SIZE(_Cla1funcsLoadSize),
PAGE = 0, ALIGN(4)
#endif //CLA_BLOCK_INCLUDED
#else
codestart : > BEGIN, PAGE = 0
ramfuncs : > RAMM0 PAGE = 0
#ifdef CPU1
.text : >>RAMM0 | RAMD0 | RAMLS_PROG | RAMGS_PROG, PAGE = 0
#else
.text : >>RAMM0 | RAMD0 | RAMLS_PROG, PAGE = 0
#endif
.cinit : > RAMM0 | RAMD0 | RAMLS_PROG | RAMGS_PROG, PAGE = 0
.pinit : > RAMM0, PAGE = 0
.switch : > RAMM0, PAGE = 0
.econst : > RAMLS_DATA, PAGE = 1
/* Allocate IQ math areas: */
IQmath : > RAMLS_PROG, PAGE = 0 /* Math Code */
IQmathTables : > RAMLS_PROG, PAGE = 0
#ifdef CLA_BLOCK_INCLUDED
/* CLA specific sections */
Cla1Prog : > RAMLS_CLA_PROG, PAGE=0
#endif //CLA_BLOCK_INCLUDED
#endif
.stack : > RAMM1, PAGE = 1
#ifdef CPU1
.ebss : >> RAMLS_DATA| RAMD1 | RAMGS_DATA , PAGE = 1
#else
.ebss : >> RAMLS_DATA| RAMD1, PAGE = 1
#endif
.reset : > RESET, PAGE = 0, TYPE = DSECT /* not used, */
.esysmem : > RAMLS_DATA, PAGE = 1
#ifdef CLA_BLOCK_INCLUDED
/* CLA C compiler sections */
//
// Must be allocated to memory the CLA has write access to
//
Cla1DataRam0 : > RAMLS_CLA_DATA, PAGE=1
Cla1ToCpuMsgRAM : > CLA1_MSGRAMLOW, PAGE = 1
CpuToCla1MsgRAM : > CLA1_MSGRAMHIGH, PAGE = 1
CLAscratch :
{ *.obj(CLAscratch)
. += CLA_SCRATCHPAD_SIZE;
*.obj(CLAscratch_end) } > RAMLS_CLA_DATA, PAGE = 1
.scratchpad : > RAMLS_CLA_DATA, PAGE = 1
.bss_cla : > RAMLS_CLA_DATA, PAGE = 1
.const_cla : LOAD = FLASHA_N,
RUN = RAMLS_CLA_DATA,
RUN_START(_Cla1ConstRunStart),
LOAD_START(_Cla1ConstLoadStart),
LOAD_SIZE(_Cla1ConstLoadSize),
PAGE = 1
#endif //CLA_BLOCK_INCLUDED
#ifdef CPU1
/* The following section definitions are required when using the IPC API Drivers */
GROUP : > CPU1TOCPU2RAM, PAGE = 1
{
PUTBUFFER
PUTWRITEIDX
GETREADIDX
WRITEFLAG1CPU1
WRITEFLAG2CPU1
READFLAG1CPU1
READFLAG2CPU1
}
GROUP : > CPU2TOCPU1RAM, PAGE = 1
{
GETBUFFER : TYPE = DSECT
GETWRITEIDX : TYPE = DSECT
PUTREADIDX : TYPE = DSECT
WRITEFLAG1CPU2: TYPE = DSECT
WRITEFLAG2CPU2: TYPE = DSECT
READFLAG1CPU2: TYPE = DSECT
READFLAG2CPU2: TYPE = DSECT
}
#else
/* The following section definitions are required when using the IPC API Drivers */
GROUP : > CPU2TOCPU1RAM, PAGE = 1
{
PUTBUFFER
PUTWRITEIDX
GETREADIDX
WRITEFLAG1CPU2
WRITEFLAG2CPU2
READFLAG1CPU2
READFLAG2CPU2
}
GROUP : > CPU1TOCPU2RAM, PAGE = 1
{
GETBUFFER : TYPE = DSECT
GETWRITEIDX : TYPE = DSECT
PUTREADIDX : TYPE = DSECT
WRITEFLAG1CPU1: TYPE = DSECT
WRITEFLAG2CPU1: TYPE = DSECT
READFLAG1CPU1 : TYPE = DSECT
READFLAG2CPU1 : TYPE = DSECT
}
#endif
GROUP : > RAMGS_IPCBuffCPU1, PAGE = 1
{
CPU1TOCPU2GSRAM
}
GROUP : > RAMGS_IPCBuffCPU2, PAGE = 1
{
CPU2TOCPU1GSRAM
}
}
/*
//===========================================================================
// End of file.
//===========================================================================
*/
几 个月前、我问了一个类似的问题、因为我遇到了相同的错误("程序将无法放入可用存储器")、我假设通过 MATLAB Simulink 增大堆大小可以解决这个问题。 它暂时确实如此，但现在我仍有同样的问题。
