[参考译文] DRV8244S-Q1LEVM：使用 Arduino 进行 SPI 控制

嗨、Ankit、

请参阅以下/随附代码、我已经使用 DRV8244S-Q1EVM 对其进行了测试。   e2e.ti.com/.../DRV8244S_2D00_Q1_2D00_Arduino_2D00_SPI.ino

我将所有引脚从 EVM 跳至 Arduino Uno、但 IPROPI 引脚除外。  确保使用 J4接头的右侧(驱动器侧)、因为左侧连接到 EVM 微控制器而不是驱动器。  

#include <SPI.h>

// SPI Protocol
#define SPI_ADDRESS_MASK   0x3F00        // Mask for SPI register address bits
#define SPI_ADDRESS_POS    8             // Position for SPI register address bits
#define SPI_DATA_MASK      0x00FF        // Mask for SPI register data bits
#define SPI_DATA_POS       0             // Position for SPI register data bits
#define SPI_RW_BIT_MASK    0x4000        // Mask for SPI register read write indication bit

// Arduino CLK = PIN 13
// Arduino SDI (MISO) = PIN 12
// Arduino SDO (MOSI) = PIN 11
#define CS_PIN 10
#define NSLEEP_PIN 9
#define NFAULT_PIN 8
#define IN2_PIN 6                     
#define IN1_PIN 7
#define DRVOFF_PIN 5

// Brushed DC Motor Connected between OUT1 and OUT2 on DRV8244S-Q1EVM
// All jumpers on J4 removed except IPROPI

void setup() {
  pinMode(NSLEEP_PIN, OUTPUT);  digitalWrite(NSLEEP_PIN,  1);
  pinMode(CS_PIN, OUTPUT);      digitalWrite(CS_PIN, 1);
  pinMode(IN2_PIN, OUTPUT);     digitalWrite(IN2_PIN, 0);
  pinMode(IN1_PIN, OUTPUT);     digitalWrite(IN1_PIN, 0);
  pinMode(NFAULT_PIN, OUTPUT);  digitalWrite(NFAULT_PIN, 0);
  pinMode(DRVOFF_PIN, OUTPUT);  digitalWrite(DRVOFF_PIN, 0);

  delay(5);

  SPI.begin();         // initialize the SPI library
  SPI.setDataMode(SPI_MODE1);

  write8(0x08, 0b10000000); // Send CLR_FLT command
  delay(5);

  // Enter PWM Mode
  write8(0x0C, 0b01000011); // set S_MODE = 0b11 for PWM mode
  digitalWrite(DRVOFF_PIN, 0);

}

void loop() {

  // Accelerate
  for (int i = 0; i < 255; i++)
  {
    analogWrite(IN2_PIN, i);
    delay(2);
  }
  delay(1000);

  // Decelerate
  for (int i = 255; i >0; i--)
  {
    analogWrite(IN2_PIN, i);
    delay(2);
  }
  delay(500);

}

void write8(uint8_t reg, uint8_t value) {

  // This SPI function is used to write the set device configurations and operating
  // parameters of the device.
  // Register format |R/W|A5|A4|A3|A2|A1|A0|*|D7|D6|D5|D4|D3|D2|D1|D0|
  // Ax is address bit, Dx is data bits and R/W is read write bit.
  // For write R/W bit should 0.

  volatile uint16_t reg_value = 0; // Variable for the combined register and data info
  reg_value |= ((reg << SPI_ADDRESS_POS) & SPI_ADDRESS_MASK);         // Adding register address value
  reg_value |= ((value << SPI_DATA_POS) & SPI_DATA_MASK);             // Adding data value

  digitalWrite(CS_PIN, LOW);

  SPI.transfer((uint8_t)((reg_value>>8) & 0xFF));
  SPI.transfer((uint8_t)(reg_value & 0xFF));

  digitalWrite(CS_PIN, HIGH);
}

我的代码使用这行 PWM 控制模式：

此致！

雅各布

嗨、Ankit、

请参阅 器件数据表中的8.3.3.2 IPROPI：

AIPROPI 为4570或4750、具体取决于封装：

因此、如果驱动器以1A (I_hs + I_LS = 1A)的速度运行、则 IPROPI = 1A/4750A/A = (1/4750) A。

然后使用您在 EVM 上选择的 IPROPI 电阻器-假设它位于1kΩ。  IPROPI*(1/4750) A = 1000Ω 引脚上的0.210V V =。  

此致！

雅各布