[参考译文] TMS320F280025：HWBIST 测试后的虚假中断

Andrea、

我想我得到了答案、在 stl_hwbist_s.asm 文件中假设用户正在清除计时器 ISR 中的 TIF (计时器中断标志)位15。  但是、对于重复的计时器 ISR、清除 TIF 位并非绝对必要、因此我需要您检查是否在计时器2 ISR 中执行此操作。  

如果未清除 TIF、那么您将在每次 HWBIST 运行时获得一个计时器2 INT (这是您看到的内容)。即使您清除该位、也可能会发生这种情况、但这会假设计时器2周期与微运行之间的时间~μ s 相同、我认为情况并非如此。

背景如下：

在我们在 HWBIST 微运行之前启用中断记录之前、我们先保存 Timer1和 timer2 TCR 寄存器(包含 TIF 和 tie (计时器中断使能)的状态、然后再清除 tie 位以避免虚假 ISR、如上所述

        MOVW    DP, #TmrRegs
        MOV     AL, @TMR1TCR            ; Save TCR registers in the ACC
        MOV     AH, @TMR2TCR

        AND     @TMR1TCR, #~(3 << 14)   ; Clear TIE bit without clearing TIF
        AND     @TMR2TCR, #~(3 << 14)   ; Clear TIE bit without clearing TIF

        EALLOW

        MOVW    DP, #HWBRegs
        MOVW    @CSTCGCR3, #0x0A        ; Start logging interrupts

现在、当我们从微运行恢复上下文恢复时、我们在以下代码中重新查看 TCR 寄存器的存储版本。

   ; Restore the CPU Timer 1 & 2 interrupt enable status. If the TCR.TIF bit
    ; is set and interrupts were enabled force the corresponding bit in IFR.
    ;
        MOVW    DP, #TmrRegs

        TBIT    AL, #14             ; Branch if TIE wasn't set
        SB      noEnableTIE1, NTC

        TBIT    @TMR1TCR, #15       ; Branch if TIE was set, but TIF isn't
        SB      enableTIE1, NTC
        OR      IFR, #(1 << 12)     ; Set the IFR flag for INT13

enableTIE1:
        MOV     AL, @TMR1TCR        ; Reenable CPU Timer 1 interrupts
        AND     AL, #~(1 << 15)     ; TIF is W1C, so take care not to clear it
        OR      AL, #(1 << 14)
        MOV     @TMR1TCR, AL

noEnableTIE1:
        TBIT    AH, #14             ; Check if TIE was set
        SB      noEnableTIE2, NTC

        TBIT    @TMR2TCR, #15       ; Branch if TIE was set, but TIF isn't
        SB      enableTIE2, NTC
        OR      IFR, #(1 << 13)     ; Set the IFR flag for INT14

enableTIE2:
        MOV     AL, @TMR2TCR        ; Reenable CPU Timer 2 interrupts
        AND     AL, #~(1 << 15)     ; TIF is W1C, so take care not to clear it
        OR      AL, #(1 << 14)
        MOV     @TMR2TCR, AL

noEnableTIE2:

如果没有设置 TIE 位(意味着用户没有使用计时器中断)、我们跳到下一个计时器、因为我们不关心 TIF (根据计时器的工作方式、这些计时器在复位后启用、因此即使未使用、也会设置 TIF)。

本例中、由于未使用计时器1、因此我们跳过它并继续介绍计时器2。

现在、由于计时器2设置了连接、我们完成了评估、然后继续评估位15 TIF。  如果在我们启动 HWBIST 之前设置了它、则假设我们在为 ISR 提供服务之前捕获了它、因此在我们返回时需要为其提供服务。

如果用户未有意清除计时器2 ISR 中的 TIF、则始终设置该位；因此 ASM 代码将手动设置与计时器2相对应的 IFR 位。

因此、我们有两种选择：

1)清除计时器2 ISR 中的 TIF 位。  我认为这是最简单的

2)更改代码  stl_hwbist_s.asm 以在保存上下文时特意清除 TIF 位。  最糟糕的是、这会将计时器2 ISR 延迟一个计时器2周期。  这样做的缺点是我们必须重新编译 stl_diagnostic.lib、因为 asm 文件是该库的一部分。  该工程确实存在于 C2000Ware 中、因此不会太难、而是需要额外执行一个步骤、具体取决于您要如何继续。

此致、
Matthew