[参考译文] MCF8316A：没有 uC 时电机不旋转

我想指定向 SPEED 引脚施加介于2.3-3V 之间的模拟电压

尊敬的 Vinsch：

您是否已为电机配置/调优 MCF8316A 寄存器？ MCF8316A 需要对其寄存器设置进行一些基本的调优(具体取决于您的电机)、然后才能使电机旋转。

如果要在没有外部微控制器的情况下使用该寄存器、则需要将寄存器设置编程到器件的内部 EEPROM 寄存器存储器中、以便在上电时加载这些设置。 可以使用 I2C 对寄存器进行配置/编程(请参阅数据表第7.6节" EEPROM 访问和 I2C 接口")。

这些基本的设置包括：

• 电机参数
  • 电机相电阻[MOTOR_RES]
  • 电机相电感[MOTOR_IND]
  • 电机 BEMF 常数[MOTOR_BEMF_CONST]
  • 速度环路 Kp [SPD_LOOP_KP]
  • 速度环路 Ki [SPD_LOOP_KI]
  • 如果在上述5个参数中的任何一个为0时发出速度命令、则器件将自动尝试运行其内置的电机参数提取工具(MPET)算法来测量这些值。
  • 如果 MPET 无法测量这些值、可能需要手动输入这些参数。   有关更多详细信息、请参阅此 E2E 常见问题解答。
• 最大速度[MAX_SPEED]

您还需要针对您的电机/应用调整和优化许多其他寄存器设置、例如各种电流限制、加速率、故障配置等

有关如何调整各种参数的说明、请参阅 MCF8316A 调优指南。

此致、
Eric C.

尊敬的 Vinsch：

只是想确认您的 MCF8316AEVM 不正确吗？ EVM + GUI 可能是为您的电机配置/调优器件寄存器的最简单方法。

关于你的 Arduino 代码,我不确定,但 Wire.write ()命令可能会 自动发送起始条件以及目标地址和 R/W 位,所以你可能只需要提供24位控制字。 此外、我会将 CRC_EN 设置为0、以避免需要计算/传输额外的 CRC 字节。 因此、我会尝试更改 control_word1[]=｛0x10、 0x00、 0x8A｝；

您还可以参阅此 E2E 常见问题解答、了解如何使用 MSP430FR2355 LaunchPad 通过 I2C 对 MCx 器件进行编程/通信：
https://e2e.ti.com/support/motor-drivers-group/motor-drivers/f/motor-drivers-forum/1246892/faq-program-mcx-bldc-motor-driver-through-i2c-using-msp430-launchpad

使用 MSP430FR2355 LaunchPad 的示例项目、您应该可以轻松地修改代码以读取/写入 MCF8316A 器件中的任何寄存器。

此致、
Eric C.

尊敬的 Vinsch：

您能否在 Arduino 上尝试以下代码：

#include <Wire.h>

void setup()
{
  Serial.begin(115200);
  
  Wire.begin();
  Wire.setClock(100000);
  
  read32(0x80);  // 32-bit read register 0x80
  write32(0x80, 0x12345678);  // 32-bit write  to register 0x80
  read32(0x80);  // 32-bit read register 0x80
}

void loop()
{
}

void read32(int reg_addr)
{
  byte reg_addr_H = (reg_addr & 0x0F00) >> 8;
  byte reg_addr_L = (reg_addr & 0xFF);
  
  const byte control_word[] = {0x90, reg_addr_H, reg_addr_L}; // 24-bit control word (CRC_EN = 0)
 
  Wire.beginTransmission(0x01);
  Wire.write(control_word, 3); // send the control word
  Wire.endTransmission();

  Wire.requestFrom(0x01, 4);    // request 4 bytes (32-bit read)

  unsigned long register_value = 0;
  for (int i = 0; i < 4; i++)
  {
    unsigned long c = Wire.read(); // receive a byte as character
    register_value |= (c << (i * 8)); // reconstruct 32-bit value (LSB is received first)
//    Serial.println(c, HEX);         // print each received byte
  }
  
  Serial.print("Finished reading register: 0x");
  Serial.println(reg_addr, HEX);
  Serial.print("Value = 0x");
  Serial.println(register_value, HEX);
}

void write32(int reg_addr, unsigned long writedata)
{
  byte reg_addr_H = (reg_addr & 0x0F00) >> 8;
  byte reg_addr_L = (reg_addr & 0xFF);
  
  const byte control_word[] = {0x10, reg_addr_H, reg_addr_L}; // 24-bit control word (CRC_EN = 0)
  byte data[] = {0x00, 0x00, 0x00, 0x00};   // 32-bit register data to be written
 
  for (int i = 0; i < 4; i++)
  {
    data[i] = ((writedata & (((unsigned long)0xFF) << (i * 8))) >> (i * 8));
  }
 
  Wire.beginTransmission(0x01);
  Wire.write(control_word, 3); // send the control word
  Wire.write(data, 4);  // send the 32-bit write data
  Wire.endTransmission();

  Serial.print("Finished writing to register: 0x");
  Serial.println(reg_addr, HEX);
}

我创建了一个简单的读取和写入函数、并验证了它们 在 MSP430FR2355 LaunchPad 上工作

此致、
Eric C.

Eric、您好！

是的、我没有 EVM 板

我尝试过该代码、这会在串行监视器上产生：

完成读取寄存器：0x80

值= 0x12345678

写入寄存器：0x80完成

完成读取寄存器：0x80

值= 0x12345678 


我接下来应该怎么做？ 您是否可以让此代码更改必要的参数？ 
(motor_res、motor_ind、motor_bemf、SPEED_LOOP_KP、SPEED_LOOP_ki) 
在寄存器 CLOSED_LOOP2、CLOSED_LOOP3和 CLOSED_LOOP4中？ 

我从数据表中了解到地址是0x8A；0x8C；0x8E 

最后、我只希望电机旋转、或者至少对相位提供一些反馈以便能够测量电机