[参考译文] AWR1843AOPEVM：AWR1843AOPEVM

王嘉晶、

您能否确认您是否对演示进行了任何更改？ 或者您是否构建了自定义应用？

此致、
Saswat Kumar

是 的、我对演示进行了一些更改，导致 L2存储器不足和编译失败、因此我们的软件工程师修改了 DSS_MMW_linker.cmd 以增加 L2存储器、修改如下：  

/*----------------------------------------------------------------------------*/
/* Linker Settings                                                            */
--retain="*(.intvecs)"

--stack_size=0x700

/* Get around a CCS issue; real-specify libraries ref'd in the overlays below. */
-ldsplib.ae64P
-llibmmwavealg_xwr18xx.ae674
-lmathlib.ae674
-llibsoc_xwr18xx.ae674
-llibmailbox_xwr18xx.ae674
-llibmmwave_xwr18xx.ae674
-llibedma_xwr18xx.ae674
-l./src/sysbios/sysbios.ae674
-l./Debug/configPkg/package/cfg/dss_mmw_pe674.oe674
-llibcrc_xwr18xx.ae674
-llibadcbuf_xwr18xx.ae674
-lrts6740_elf.lib

/*----------------------------------------------------------------------------*/
/* Section Configuration                                                      */
SECTIONS
{
    systemHeap : {} >> L2SRAM_UMAP0 | L2SRAM_UMAP1
    .l2data : {} >> L2SRAM_UMAP0 | L2SRAM_UMAP1

    /* HSSRAM has output data from processing chain running on DSP */
    .demoSharedMem > HSRAM

    /* L3SRAM has code that is overlaid with data, so data must be
       marked uninitialized. Application can initialize this section
       using _L3data_* symbols defined below. Code should be written carefully as
       these are linker symbols (see for example e2e.ti.com/.../92002 ):

        extern far uint8_t _L3data_start; // the type here does not matter
        extern far uint8_t _L3data_size;  // the type here does not matter

        memset((void *)_symval(&_L3data_start), 0, (uint32_t) _symval(&_L3data_size));
    */
    .l3data: type=NOINIT, start(_L3data_start), size(_L3data_size), load=L3SRAM PAGE 1

    /* Bootloader cannot load L1DSRAM, make sure to mark as NOINIT */
    .l1data : type=NOINIT, load=L1DSRAM

    /* Currently bootloader does not allow loading in L1PSRAM because of supporting
       low power. Below fast code is loaded in L3SRAM but run from L1PSRAM. The copy-in
       is called during initialization phase and copy-out is not used but can be added when
       supporting low-power mode (where L1 contents are not retained).
     */
    .fastCode:
    {
        dsplib.ae64P(.text)
        libmmwavealg_xwr18xx.ae674(.text)
        mathlib.ae674(.text)
        dss_data_path.oe674 (.text:MmwDemo_interFrameProcessing)
        dss_data_path.oe674 (.text:MmwDemo_processChirp)
        dss_data_path.oe674 (.text:MmwDemo_interChirpProcessing)
        dss_main.oe674 (.text:MmwDemo_dssDataPathProcessEvents)
        /* Below may be risky to expose hence currently hiding */
        // libosal_xwr16xx.ae674 (.text:SemaphoreP_pend)
        // libosal_xwr16xx.ae674 (.text:SemaphoreP_post)
        rts6740_elf.lib (.text:cos)
        rts6740_elf.lib (.text:sin)
        rts6740_elf.lib (.text:log)
        rts6740_elf.lib (.text:asin)
        rts6740_elf.lib (.text:expf)
    } load=L3SRAM PAGE 0, run=L1PSRAM PAGE 0, table(_MmwDemo_fastCode_L1PSRAM_copy_table, compression=off)

    /* This is auto generated by linker related to copy table above */
    .ovly > L2SRAM_UMAP0 | L2SRAM_UMAP1

    /* Overlay one-time/init-time (and non-critical in cycles) with L3 data,
       will be erased during data path processing. Note do not put any
       code that is required related to start/stop/reconfig processing */
    .overlay:
    {
        libsoc_xwr18xx.ae674 (.text:SOC_init)
        dss_main.oe674 (.text:MmwDemo_dssInitTask)
        dss_main.oe674 (.text:main)
        dss_data_path.oe674 (.text:MmwDemo_dataPathInitEdma)
		libsoc_xwr18xx.ae674 (.text:SOC_deviceInit)
    } > L3SRAM PAGE 0

    .text_l3:
    {
        dss_main.oe674 (.text:MmwDemo_dssDataPathInit)
    } > L3SRAM PAGE 0

    .text_l3p1:
    {
    	dss_main.oe674 (.text:MmwDemo_parseProfileAndChirpConfig)
    	/*
    	libmailbox_xwr18xx.ae674 (.text)
    	dss_mmw_pe674.oe674 (.text:xdc_runtime_System_printfExtend__I)
    	sysbios.ae674 (.text)
    	*/
    	dss_mmw_pe674.oe674 (.text:xdc_runtime_System_printfExtend__I)
    	dss_main.oe674 (.text:MmwDemo_dssSendProcessOutputToMSS)
    	libcrc_xwr18xx.ae674 (.text:CRC_open)
    	libmailbox_xwr18xx.ae674 (.text:Mailbox_open)
    	libmmwave_xwr18xx.ae674 (.text:MMWave_initMMWaveLink)
    	libmmwave_xwr18xx.ae674 (.text:MMWave_startLink)
    	libedma_xwr18xx.ae674 (.text:EDMA_open)
    	dss_main.oe674 (.text:MmwDemo_parseAdcBufCfg)
    	libadcbuf_xwr18xx.ae674 (.text:ADCBUFCmdParamCheck)
    	libmmwave_xwr18xx.ae674 (.text:MMWave_flushCfg)
        libmmwave_xwr18xx.ae674 (.text:MMWave_getChirpHandle)
        libmmwave_xwr18xx.ae674 (.text:MMWave_start)
        libadcbuf_xwr18xx.ae674 (.text:ADCBUF_MMWave_open)
        dss_main.oe674 (.text:MmwDemo_dssDataPathConfigAdcBuf)
        libedma_xwr18xx.ae674 (.text:EDMA_init)
        dss_data_path.oe674 (.text:MmwDemo_dataPathConfigBuffers)
        libmmwave_xwr18xx.ae674 (.text:MMWave_init)
        dss_main.oe674 (.text:ODSDemo_objInit)
        libmailbox_xwr18xx.ae674 (.text:Mailbox_init)
        dss_data_path.oe674 (.text:MmwDemo_dataPathConfigEdma)
        dss_data_path.oe674 (.text:MmwDemo_dataPathConfigFFTs)
        libmmwave_xwr18xx.ae674 (.text:MMWave_initCRC)
        libmmwave_xwr18xx.ae674 (.text:MMWave_initLink)
        libadcbuf_xwr18xx.ae674 (.text:ADCBUF_MMWave_close)
        libmailbox_xwr18xx.ae674 (.text:Mailbox_close)
        dss_main.oe674 (.const:.string)
        sysbios.ae674 (.const:.string)
        dss_config_edma_util.oe674 (.const:.string)
        dss_data_path.oe674 (.const:.string)
        dss_mmw_pe674.oe674 (.const:.string)
    } > L3SRAM PAGE 1
	
}
/*----------------------------------------------------------------------------*/

请帮助您查看是否存在问题？ 非常感谢！